Controlling Viewfinder tally

Questions about ATEM Switchers, Camera Converter and everything live!
  • Author
  • Message
Offline

Paul Schaer

  • Posts: 3
  • Joined: Sat Nov 11, 2017 7:06 pm

Controlling Viewfinder tally

PostSat Nov 11, 2017 7:38 pm

Is there a way to control the tally light of a Blackmagic URSA Studio Viewfinder when not used together with a Blackmagic camera?

Apparently, the tally can only be controlled via SDI, so we tried to use a Blackmagic 3G-SDI Arduino Shield to control the tally. But we couldn't make it work. In the URSA manual documents.blackmagicdesign.com/CinemaCamera/20171025-9a9df4/Blackmagic_URSA_Mini_Manual.pdf page 211 we found that there is a special "monitor tally" channel in the Blackmagic tally protocol, and from the documentation it looks like the Arduino Shield can only send the camera tally signals, but not this monitor tally.
Offline
User avatar

Xtreemtec

  • Posts: 2393
  • Joined: Wed Jan 02, 2013 11:48 am
  • Location: The Netherlands

Re: Controlling Viewfinder tally

PostMon Nov 13, 2017 10:04 pm

Monitor Tally has ID 0 instead of Camera ID 1, 2 , 3 , 4 ;)
Daniel Wittenaar .:: Xtreemtec Media Productions ::. -= www.xtreemtec.nl =-
4K OBV, ATEM TVS HD, 1M/E 4K, 2M/E Broadcast Studio 4K, Hyperdeck Studio Mini, SONY FS7 4K, Ursa Broadcast 4K
Offline

Paul Schaer

  • Posts: 3
  • Joined: Sat Nov 11, 2017 7:06 pm

Re: Controlling Viewfinder tally

PostSat Nov 18, 2017 2:40 pm

Xtreemtec wrote:Monitor Tally has ID 0 instead of Camera ID 1, 2 , 3 , 4 ;)

Thanks for your answer. Unfortunately, it's not that simple. If you look in SDITallyControl::setCameraTally, setting Tally ID 0 is not possible:
Code: Select all
      // Reject invalid camera numbers
      if (cameraNumber <= 0 || cameraNumber > (int)kRegOTDATA_Width)
         return;

And later it shifts the ID by -1:
Code: Select all
      // Update the requested camera's tally info
      regWrite8(kRegOTDATA + (cameraNumber - 1), data);

So this is not the answer.
Offline
User avatar

Xtreemtec

  • Posts: 2393
  • Joined: Wed Jan 02, 2013 11:48 am
  • Location: The Netherlands

Re: Controlling Viewfinder tally

PostMon Nov 20, 2017 6:59 pm

Hmm Weird.. I was under the impression that Monitor ID was 0. I do remember that i got that out of the Atem Camera Converters on the SDI output. (They don't output all tally info. But only ID 0 ).
Daniel Wittenaar .:: Xtreemtec Media Productions ::. -= www.xtreemtec.nl =-
4K OBV, ATEM TVS HD, 1M/E 4K, 2M/E Broadcast Studio 4K, Hyperdeck Studio Mini, SONY FS7 4K, Ursa Broadcast 4K
Offline

Gary Adams

Blackmagic Design

  • Posts: 565
  • Joined: Sat Aug 25, 2012 6:14 am

Re: Controlling Viewfinder tally

PostMon Nov 20, 2017 7:15 pm

Here is an example Arduino Shield sketch that will control the Viefinder Monitor separately. Hope this helps. Regards, Gary

Code: Select all
#include <BMDSDIControl.h>

/*

  Tally  = 1<<0=Switcher Connected, 1<<1=Preview Tally, 1<<2=Program Tally

*/

const int                shieldAddress = 0x6E;
BMD_SDICameraControl_I2C sdiCameraControl(shieldAddress);



const byte connected  = 1 << 0;           // 1 shifted left 0 times, equivalent to 1 in decimal
const byte preview    = 1 << 1;           // 1 shifted left 1 times, equivalent to 2 in decimal
const byte program    = 1 << 2;           // 1 shifted left 2 times, equivalent to 4 in decimal

byte newTally[3] = {program, preview, 0};


void setup()
{
  sdiCameraControl.begin();
  sdiCameraControl.setOverride(true);     // Turn on control overrides
}

void loop()
{
                                          // cycle through RED, GREEN and NO Tally every half second
 
  for (int i = 0; i < 3; i++)
  {
    sdiCameraControl.writeCommandInt8(
      2,                                  // Destination:    doesn't care any number between 1 and 99
      9,                                  // Category:       Switcher Status
      6,                                  // Param:          Tally
      0,                                  // Operation:      Absolute
      newTally[i]                         // Tally Status    Program -> Preview -> OFF
    );

    delay(500);
  }
}
Gary Adams
Blackmagic Design
Offline

Paul Schaer

  • Posts: 3
  • Joined: Sat Nov 11, 2017 7:06 pm

Re: Controlling Viewfinder tally

PostTue Nov 21, 2017 1:42 pm

Thanks a lot Gary, this works!

Return to Live Production

Who is online

Users browsing this forum: James Bonnett and 7 guests